Версия 3.07 Получения указателя win и обновление экрана

external(INT, "CreateProcess", "CreateProcessA", "Kernel32.dll");
external(INT, "GetWindowInfo", "GetWindowInfo", "User32.dll" );
external(INT, "GetWindowText", "GetWindowTextA", "User32.dll");
external(INT, "GetClassName", "GetClassNameA", "User32.dll");
external(INT, "FindWindowEx", "FindWindowExA", "User32.dll" );
external(INT, "GetWindowThreadProcessId", "GetWindowThreadProcessId", "User32.dll");


// Имя и класс окна можно указать частично. Для латиницы регистр игнорируется.
win w; // переменная глобальная, т. к. нельзя заполнить структуру по указателю
string path="C:\Windows\notepad.exe"; // путь к запускаемому exe
string name="Блокнот"; // имя окна, можно не указывать, если указан класс окна
string class="Notepad"; // класс окна, можно не указывать, если указано имя окна
int wait=10000; // сколько времени ожидать загрузки окна (в мсек)


int handle=start_exe(path, #name, #class, wait); // вызов функции, запустит exe и вернёт хендл окна
if(handle>0) // если хендл найден
{
w=formatiw(handle); // преобразовать хендл к win
structure_win(); // заполнить структуру
messagebox("Имя окна: "+w.name+formatic(13)+formatic(10)+"Класс окна: "+w.class);
}
else messagebox("Окно не найдено");


// функция принимает:
// путь к exe
// указатель на переменную имени окна
// указатель на переменную класса окна
// сколько времени ожидать загрузки окна (в мсек)

function start_exe(string path_to_exe, string #name_window, string #class_window, int wait_for_window)
{
int handle_window[9999], c[9999], c1[17], c2[4], pid, i, h, count_handle=0;
string temp, temp2;
char c3[255], c4[255];

for(i=0; i<sizearray(c1); i++)c1[i]=0;
writeaddress(sizearray(c1)*4, address(#c1[0]));

if(CreateProcess(path_to_exe, 0, 0, 0, 0, 32, 0, 0, address(#c1[0]), address(#c2[0])))
{
looptime(wait_for_window)
{
h=FindWindowEx(0, 0, 0, 0); // поиск всех окон
while(h && count_handle<sizearray(handle_window)){handle_window[count_handle]=h; count_handle++; h=FindWindowEx(0, h, 0, 0);}
for(i=0; i<count_handle; i++)
{
GetWindowThreadProcessId(handle_window[i], address(#pid));
if(pid==c2[2])
{
GetWindowText(handle_window[i], address(#c3[0]), sizearray(c3));
GetClassName(handle_window[i], address(#c4[0]), sizearray(c4));
if(name_window!="" || class_window!="") // если не пустые
{
if(regexsearch(1, #temp, format(#c3[0]), name_window, IGNORECASE) && regexsearch(1, #temp2, format(#c4[0]), class_window, IGNORECASE))
{
name_window=format(#c3[0]); class_window=format(#c4[0]); return handle_window[i];
}
}
else {messagebox("Требуется указать имя или класс окна"); name_window="-1"; class_window="-1"; return -1;}
}
}
}
}
return 0;
}

function structure_win()
{
int info[15];
writeaddress(sizearray(info)*4, address(#info[0]));
if(GetWindowInfo(handle, address(#info[0])))
{
w.width=info[3]-info[1]; w.height=info[4]-info[2]; w.left=info[1]; w.top=info[2]; w.widthclient=info[7]-info[5];
w.heightclient=info[8]-info[6]; w.leftclient=info[5]; w.topclient=info[6]; w.name=name; w.class=class;
}
}