TextCaptcha в визуальном редакторе

win W_Kib=window (-1, -1, -1, -1, 1261, 786, -1);
int Screen[3000][3000];
string T_Captcha;

int eCol_Kib, eX_Kib, eY_Kib;
getdisplay(eCol_Kib, eX_Kib, eY_Kib);

TextCaptcha(1, #Screen[0][0], #W_Kib, W_Kib.leftclient, W_Kib.topclient, "anti-captcha.com", 60000, "7c05f6441e18ab1776a71e791b4d44c3", 0, 0, "", #T_Captcha, 247, 347, 593, 468);
messagebox(T_Captcha);

function TextCaptcha(int ew, int #Scr, win #w, int v_x, int v_y, string serv, int t, string KEY, int regsense, int mach, string comm, string #Ot, int sx, int sy, int fx, int fy)
{
if (ew==0) savescreen(JPG, pathfolder()+"temp_capcha.jpg", sx, sy, fx, fy, -1);
if (ew==1) savescreen(JPG, pathfolder()+"temp_capcha.jpg", v_x+sx, v_y+sy, v_x+fx, v_y+fy, -1);
if (ew==2) savescreen(JPG, pathfolder()+"temp_capcha.jpg", sx, sy, fx, fy, w);
if (ew==3) saveimage(JPG, #Scr[0][0], pathfolder()+"temp_capcha.jpg", sx, sy, fx, fy);
char BYTE[200000];
int size_file=0;
string id;
string Header;
string REZ;
if (serv=="anti-captcha.com")
{
if (fopen (pathfolder()+"temp_capcha.jpg", "rb")!=0)
{
size_file=freadb(#BYTE[0], 200000);
fclose();
}
else return -5;
string file64=base64code (#BYTE[0], size_file);
string Mach="false";
if (mach)Mach="true";
string json;
json="{^"clientKey^":^""+KEY+"^"," +
"^"task^":{^"type^":^"ImageToTextTask^"" +
",^"body^":^""+file64+"^",^"math^":"+Mach+",";
json=json+"^"minLength^":0,^"maxLength^":0";
if (comm!="")json=json+",^"comment^":^""+ansitoutf8(comm)+"^"";
if (regsense)json=json+",^"case^":^"true^"";
else json=json+",^"case^":^"false^"";
json=json+"}}";
int aW=size(json);
strcpy(#BYTE[0], json);
Header="Content-Type: application/x-www-form-urlencoded";
int K=0;
A: sendgetweb(#REZ, "My bot", "POST", "https:/^/api.anti-captcha.com", "createTask", Header, #BYTE[0], aW);
if (parserjson(Rez_Json, REZ)!=1)
{
if (K>2)
{
Ot="Не подключились к сервису";
return -1;
}
K++;
pause(2000);
goto A;
}
if (Rez_Json.errorId=="0")
{
id=Rez_Json.taskId;
pause(3000);
if (t==0) t=1;
looptime(t)
{
pause(2000);
json="{^"clientKey^":^""+KEY+"^",^"taskId^": "+id+"}";
aW=size(json);
strcpy(#BYTE[0], json);
sendgetweb(#REZ, "My bot", "POST", "https:/^/api.anti-captcha.com", "getTaskResult", Header, #BYTE[0], aW);
if (parserjson(Rez_Json, REZ)!=1)continue;
if (Rez_Json.errorId!="0")
{
Ot=Rez_Json.errorId;
return -2;
}
if (Rez_Json.status=="ready")
{
Ot=Rez_Json.solution.text;
return 1;
}
}
}
else
{
Ot=Rez_Json.errorCode;
return -3;
}
Ot="Ошибка";
return -4;
}
if (serv=="rucaptcha.com")
{
string H="--kibor-post^r^n";
H=H+"Content-Disposition: form-data; name=^"method^"^r^n^r^n";
H=H+"post^r^n";
H=H+"--kibor-post^r^n";
H=H+"Content-Disposition: form-data; name=^"key^"^r^n^r^n";
H=H+KEY+"^r^n";
if (comm!="")
{
H=H+"--kibor-post^r^n";
H=H+"Content-Disposition: form-data; name=^"textinstructions^"^r^n^r^n";
H=H+ansitoutf8(comm)+"^r^n";
}
if (regsense)
{
H=H+"--kibor-post^r^n";
H=H+"Content-Disposition: form-data; name=^"regsense^"^r^n^r^n";
H=H+"1^r^n";
}
if (mach)
{
H=H+"--kibor-post^r^n";
H=H+"Content-Disposition: form-data; name=^"calc^"^r^n^r^n";
H=H+"1^r^n";
}
H=H+"--kibor-post^r^n";
H=H+"Content-Disposition: form-data; name=^"file^"; filename=^"temp_capcha.jpg^"^r^n";
H=H+"Content-Type: image/jpeg^r^n^r^n";
strcpy(#BYTE[0], H);
int S=size(H);
if (fopen (pathfolder()+"temp_capcha.jpg", "rb")!=0)
{
size_file=freadb(#BYTE[S], 200000-S);
fclose();
}
else return -5;
size_file=size_file+S;
strcpy(#BYTE[size_file], "^r^n--kibor-post");
size_file=size_file+14;
Header="Content-Type: multipart/form-data; boundary=kibor-post";
if (sendgetweb(#REZ, "My bot", "POST", "https:/^/rucaptcha.com", "in.php", Header, #BYTE[0], size_file))
{
if (regexsearch(1, #id, REZ, "(?<=OK\|)(\d+)")==0){Ot=REZ; return -1;}
pause(3000);
if (t==0) t=1;
looptime(t)
{
pause(2000);
if (sendgetweb(#REZ, "My bot", "POST", "https:/^/rucaptcha.com", "res.php?key="+KEY+"&action=get&id="+id))
{
if (regexsearch(1, #Ot, REZ, "ERROR")){Ot=REZ; return -6;}
if (regexsearch(1, #Ot, REZ, "(?<=OK\|)(.*)+"))
{
Ot=utf8toansi(Ot);
return 1;
}
}
}
}
else
{
Ot=REZ;
return -3;
}
Ot="Ошибка";
return -4;
}
}