Версия 6.03 Получение от Телеграма и отправка сообщений в Телеграм

Добро пожаловать в телеграм Кибор Бот!

Перейдите по ссылке что бы иметь возможность отправлять Кибору комнды из Телеграма:

string token = "97654321:AAG3v_bgRV6-wIyYe9JEt5eEA";
string chat_id = "12345789";

send_photo_tg("D:\screenshot.bmp", "This is caption");


function send_photo_tg(string file_path, string caption)
{
external(INT, "DeleteFile", "DeleteFileA", "kernel32.dll");
string log_path = tempfolder()+"tg_response.txt";
string response, temp;
if(fopen(file_path, "rb") == 0) {messagebox("File not found:^n^n"+file_path); return 0;} else fclose();

temp = "curl -s -F chat_id="+chat_id;
temp = temp + " -F photo=@"+file_path;
if (size(caption) > 0) temp = temp + " -F caption=^""+caption+"^"";
temp = temp + " ^"https:/"+"/api.telegram.org/bot"+token+"/sendPhoto^"";
temp = temp + " > "+log_path+" 2>&1";
system(temp);
if(fopen(log_path, "r"))
{
while (freadline(temp) > 0) response = response + temp;
fclose();
} else messagebox("Error open "+log_path);
if (regexsearch(1, #temp, response, "^"ok^":true")==0) messagebox("Error send Telegram:^n^n"+response);
DeleteFile(log_path);
return 1;
}

int tg_offset=0; // update_id+1 последнего прочитанного
int tg_debug=1; // 1 = показывать сырой ответ (для отладки). Потом поставь 0.

// -------- ДЕМО (убери при вставке в свой бот) --------
string DEMO_TOKEN = "023456789:AAAA333_QAAAAAAWWDWD_dasdasd";
string DEMO_CHATID = "1111111111";

TG_reset(DEMO_TOKEN, DEMO_CHATID);
TG_send(DEMO_TOKEN, DEMO_CHATID, "Бот запущен");

string DemoRez;
loop()
{
if(TG_get(DEMO_TOKEN, DEMO_CHATID, #DemoRez))
{
messagebox("Пришло: [" + DemoRez + "]");
if(DemoRez=="1") beep(1000, 500);
if(DemoRez=="2") beep(3000, 500);
}
pause(1500);
}
// -------------------- конец демо --------------------


// Ищет в buf строку startd, возвращает в out символы после неё до кода endcode.
// endcode - ASCII код символа-ограничителя (34 = кавычка, 44 = запятая).
// Возврат 1 если найдено, 0 если нет.
function TgBetween(char #buf, string startd, int endcode, string #out)
{
char sd[512];
char res[16384];
int blen, sdlen, i, j, k, ok, start;

out = "";
strcpy(#sd[0], startd);
blen = size(#buf[0]);
sdlen = size(startd);

start = -1;
for(i=0; i<=blen-sdlen; i++)
{
ok=1;
for(j=0; j<sdlen; j++) { if(buf[i+j]!=sd[j]) { ok=0; break; } }
if(ok) { start=i+sdlen; break; }
}
if(start<0) return 0;

k=0;
for(i=start; i<blen; i++)
{
if(formatci(buf[i])==endcode) break;
res[k]=buf[i]; k++;
}
res[k]=0;
out = format(#res[0]);
return 1;
}

// URL-кодирование (cp1251 -> UTF-8 -> %XX)
function UrlEncode(string s)
{
string utf, out;
char c[8192];
char hex[17];
int i, b, hi, lo, n;

utf = ansitoutf8(s);
strcpy(#c[0], utf);
n = size(utf);
strcpy(#hex[0], "0123456789ABCDEF");
out = "";

for(i=0; i<n; i++)
{
b = formatci(c[i]);
if(b<0) b = b + 256;

if((b>=48 && b<=57) || (b>=65 && b<=90) || (b>=97 && b<=122) || b==45 || b==95 || b==46 || b==126)
{
out = out + c[i];
}
else
{
hi = b/16;
lo = b - hi*16;
out = out + "%";
out = out + hex[hi];
out = out + hex[lo];
}
}
return out;
}

// Отправить сообщение. 1 = успех, 0 = ошибка.
function TG_send(string token, string chat_id, string text)
{
char resp[8192];
string path, okv;
int r;

path = "bot"+token+"/sendMessage?chat_id="+chat_id+"&text="+UrlEncode(text);
r = sendgetweb(#resp[0], "KiborBot", "GET", "https:/^/api.telegram.org", path, 7000);
if(r <= 0) return 0;

if(TgBetween(#resp[0], "^"ok^":", 44, #okv) > 0) { if(okv=="true") return 1; }
return 0;
}

// Принять одно новое сообщение. out -> текст. 1 = получено, 0 = нет.
function TG_get(string token, string chat_id, string #out)
{
char resp[16384];
string path, uid, txt;
int r;

out = "";
path = "bot"+token+"/getUpdates?offset="+format(tg_offset)+"&limit=1&timeout=0";
r = sendgetweb(#resp[0], "KiborBot", "GET", "https:/^/api.telegram.org", path, 7000);
if(r <= 0) return 0;

if(TgBetween(#resp[0], "^"update_id^":", 44, #uid) <= 0) return 0; // сообщений нет
if(tg_debug) messagebox("Сырой ответ:^n^n"+format(#resp[0]));
tg_offset = formatsn(uid) + 1;

if(TgBetween(#resp[0], "^"text^":^"", 34, #txt) > 0) out = utf8toansi(txt);
return 1;
}

// Пропустить старые сообщения (один раз при старте).
function TG_reset(string token, string chat_id)
{
char resp[16384];
string uid;

if(sendgetweb(#resp[0], "KiborBot", "GET", "https:/^/api.telegram.org", "bot"+token+"/getUpdates?offset=-1&limit=1", 7000) > 0)
{
if(TgBetween(#resp[0], "^"update_id^":", 44, #uid) > 0) tg_offset = formatsn(uid) + 1;
}
}