string path_setting="C:\account.ini"; // путь для сохранения логинов и паролей
int count_account=3; // сколько аккаунтов


int current_dialog=0; // текущий диалог, не менять
external (INT, "GetPrivateProfileString", "GetPrivateProfileStringA", "kernel32.dll");
external (INT, "WritePrivateProfileString", "WritePrivateProfileStringA", "kernel32.dll");


string Account[10][2]; //массив для логинов и паролей
// Account[0][0] - логин для первого аккаунта Account[0][1] - пароль для первого аккаунта
// Account[1][0] - логин для второго аккаунта Account[1][1] - пароль для второго аккаунта


// Диалог1
int pos_size_button0[2][4];
string text_button0[2];
int flag_button0[2];

pos_size_button0[0][0]=10; pos_size_button0[0][1]=10; pos_size_button0[0][2]=100; pos_size_button0[0][3]=20;
pos_size_button0[1][0]=10; pos_size_button0[1][1]=40; pos_size_button0[1][2]=100; pos_size_button0[1][3]=20;

text_button0[0]="Account"; text_button0[1]="Загрузить акк";

createdialog(0, BUTTON, #pos_size_button0[0][0], #text_button0[0], #flag_button0[0]);
//////////


// Диалог2
int pos_size_button1[2][4];
string text_button1[2];
int flag_button1[2];

pos_size_button1[0][0]=120; pos_size_button1[0][1]=105; pos_size_button1[0][2]=100; pos_size_button1[0][3]=20;
pos_size_button1[1][0]=10; pos_size_button1[1][1]=105; pos_size_button1[1][2]=100; pos_size_button1[1][3]=20;
text_button1[0]="Назад"; text_button1[1]="Сохранить";

//////////

int pos_size_edit1[3][4];
string text_edit1[3];

pos_size_edit1[0][0]=80; pos_size_edit1[0][1]=10; pos_size_edit1[0][2]=100; pos_size_edit1[0][3]=20;
pos_size_edit1[1][0]=80; pos_size_edit1[1][1]=40; pos_size_edit1[1][2]=100; pos_size_edit1[1][3]=20;
pos_size_edit1[2][0]=80; pos_size_edit1[2][1]=70; pos_size_edit1[2][2]=100; pos_size_edit1[2][3]=20;
text_edit1[0]=""; text_edit1[1]=""; text_edit1[2]="";

//////////

int pos_size_static1[3][4];
string text_static1[3];

pos_size_static1[0][0]=10; pos_size_static1[0][1]=13; pos_size_static1[0][2]=60; pos_size_static1[0][3]=20;
pos_size_static1[1][0]=10; pos_size_static1[1][1]=43; pos_size_static1[1][2]=60; pos_size_static1[1][3]=20;
pos_size_static1[2][0]=10; pos_size_static1[2][1]=73; pos_size_static1[2][2]=60; pos_size_static1[2][3]=20;
text_static1[0]="Номер акк"; text_static1[1]="Login"; text_static1[2]="Password";

//////////

createdialog(1, BUTTON, #pos_size_button1[0][0], #text_button1[0], #flag_button1[0] |
EDIT, #pos_size_edit1[0][0], #text_edit1[0] |
STATIC, #pos_size_static1[0][0], #text_static1[0]);
//////////

showdialog(0, "Диалог1", 827, 428, 211, 176, 1, 1);
//////////

enabletimer(0);


loop()
{
// тут скрипт
sleep(10);
}


// функция загрузки логинов и паролей в массив Account
function load_account(string #a, int count)
{
if(fopen (path_setting, "r") > 0) // если файл с настройками открылся
{
fclose();
char load_acc[100]; // массив для получения логина/пароля из ini файла
resettextout(1);
textbkcolor(255, 16777088);
for(int i=0;i<count;i++)
{
if(GetPrivateProfileString("Account"+format(i+1), "Login", 0, address (#load_acc[0]), 100, path_setting) > 0) // загрузить логин
a[i][0]=format (#load_acc[0]);
if(GetPrivateProfileString("Account"+format(i+1), "Password", 0, address (#load_acc[0]), 100, path_setting) > 0)// загрузить пароль
a[i][1]=format (#load_acc[0]);
textout(i, 300, 300+i*20, a[i][0]+" "+a[i][1], 1); // можно убрать
}
sleep(2000); // можно убрать
resettextout(1); // можно убрать
}
else
{
resettextout(1); textbkcolor(255, 16777088);
textout(0, 300, 300, "Файл "+path_setting+" не найден", 1); // можно убрать
sleep(1500); resettextout(1);
}
}

// функция сохранения введённых логина и пароля
function save_account()
{
WritePrivateProfileString ("Account"+text_edit1[0], "Login", text_edit1[1], path_setting); // сохранить логин
WritePrivateProfileString ("Account"+text_edit1[0], "Password", text_edit1[2], path_setting); // сохранить пароль
}


CREATE_TIMER(0, 200)
{
if(current_dialog==0) // текущий диалог1, т. е. проверются нажатие кнопок основного диалога
{
if(flag_button0[0]==1) // если нажата 'Account'
{
flag_button0[0]=0;
current_dialog=1; // текущий диалог
showdialog(1, "Диалог2", 742, 402, 234, 175, 2, 1);
}

if(flag_button0[1]==1) // если нажата 'Загрузить акк'
{
flag_button0[1]=0;
load_account(#Account[0][0], count_account); // функция загрузки
}
}
else // диалог2, проверяются кнопки диалога2
{
flag_button0[0]=0; flag_button0[1]=0; // флаги кнопок диалога1 обнуляются
if(flag_button1[0]==1) // если нажата назад
{
flag_button1[0]=0;
current_dialog=0;
hidedialog(1); // скрыть диалог
}
if(flag_button1[1]==1) // если нажата сохранить
{
flag_button1[1]=0;
save_account(); // функция сохранения
resettextout(1);
textbkcolor(13703910, 16777088);
textout(100, 300, 400, "Аккаунт сохранён", 1);
sleep(1000); resettextout(1);
text_edit1[0]=""; text_edit1[1]=""; text_edit1[2]=""; // очищаем все поля
}
}
}